TK90X I/O Expander - Experiência 1

Leitura de tensões de 0 a 5VDC


Nessa experiência eu proponho a leitura de uma tensão entre 0 e 5VDC (que pode ser facilmente ampliada com a adição de um simples divisor de tensão) utilizando o microcomputador TK90X.

O circuito



Na figura acima mostro o circuito utilizado nessa experiência. O mesmo foi montado junto do protótipo para a placa TK90X I/O Expander conforme imagem abaixo. É recomendável utilizar resistores de "pull-up" em todos os pinos de PA0 a PA7, PC0 e PC4 a PC7. O valor que eu usei foi de 10k, mas valores entre 4k7 e 10k são admitidos.




O programa

Abaixo o programa desenvolvido em BASIC. Esse programa eu desenvolvi usando o simulador SpecEmu 2.9 e testei o mesmo usando o meu TK90X. Clique aqui para fazer o downloado do arquivo ".TAP" caso você não curta digitar programas (será?).

10 REM PROGRAMA ADC0804
20 REM TESTE DO CONVERSOR AD
30 REM PRESENTE NA PLACA IO
40 REM EXPANDER TK90X
50 REM DESENVOLVIDO POR
60 REM ENG. MARCIO JOSE SOARE
70 REM V1.0 - 13/07/2021
75 GOSUB 300
80 CLS
90 PRINT "LENDO DADO DO ADC"
94 PRINT "DADO AD (PORTA)="
95 PRINT "DADO PORTC="
100 PRINT "TENSAO:"
110 GOSUB 400
130 FOR I=0  TO 200: NEXT I
140 GOTO 80
300 PRINT "CONFIGURANDO 8255"
310 PRINT "PORTA=IN"
320 PRINT "PORTB=OUT"
330 PRINT "PORTC=IN/OUT"
340 OUT 59,145
350 OUT 27,85
360 OUT 43,255
370 RETURN
400 REM LIGA CS E WR
410 OUT 43,175: REM LIGA CS
420 FOR I=1 TO 5: NEXT I
430 OUT 43,255: REM DESL WR CS
440 FOR I=0 TO 5: NEXT I
450 LET A=IN 43
460 IF A<>240  THEN GO TO 450
470 OUT 43,207: REM LIGA RD CS
490 LET B=IN 11
500 OUT 43,255: REM DESL WR CS
510 GOSUB 600
520 RETURN
600 PRINT AT 1,17;B
610 PRINT AT 2,12;A
620 LET C=5000/255
630 LET C=(C*B)/1000
640 PRINT AT 3,8;C;"V"
650 OUT 27,B
660 RETURN



Conclusão

Espero que com essas dicas você que curte também o TK90X e/ou outro representante da linha Spectrum venha a se interessar em descobrir um mundo "fora da caixa" desse pequeno notável. Muitos são os controles possíveis utilizando a placa TK90X I/O Expander e em breve trarei novas e interessantes experiências. Até breve!!!




Copyright deste conteúdo reservado para Márcio José Soares e protegido pela Lei de Direitos Autorais LEI N° 9.610, de 19 de Fevereiro de 1998. É estritamente proibida a reprodução total ou parcial do conteúdo desta página em outros pontos da internet, livros ou outros tipos de publicações comerciais ou não, sem a prévia autorização por escrito do autor.